home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1992 …SCII & the Runetime Code / ADC Developer CD (1992-07) (''Butch ASCII And The Runtime Code'')_iso / Dev.CD 199207.iso / Development Platforms / Apple II / System Software (8-bit) / Disk Images / ProDOS Users Disk / LABELS.bas < prev    next >
Encoding:
BASIC Source File  |  1984-06-12  |  3.2 KB  |  66 lines
  1. 100  REM *********************
  2. 102  REM *                   *
  3. 104  REM *   LABEL PRINTER   *
  4. 106  REM *        BY         *
  5. 108  REM * GROVER F. NUNNERY *
  6. 110  REM *                   *
  7. 112  REM *********************<CTRL-J>
  8. 114  TEXT : SPEED= 255
  9. 116  IF ( PEEK( -2049) = 120)  THEN  PRINT  CHR$(21): REM TURN OFF A//E TEXT CARD
  10. 118  NORMAL : HOME 
  11. 120 D$ =  CHR$(4): REM CTRL-D
  12. 122  VTAB 4: HTAB 13: PRINT "PRINTER SLOT #1"; CHR$(8);: GET SLOT$
  13. 124  IF (SLOT$ =  CHR$(13))  THEN SLOT$ = "1"
  14. 126  IF (SLOT$ <"1")  OR (SLOT$ >"7") GOTO 122
  15. 128  PRINT SLOT$:SLOT =  VAL(SLOT$)
  16. 130  VTAB 10: HTAB 13: PRINT "A(DDRESS LABELS"
  17. 132  HTAB 13: PRINT "S(HIPPING LABELS"
  18. 134  HTAB 13: PRINT "E(NVELOPES"
  19. 136  HTAB 13: PRINT "Q(UIT"
  20. 138  PRINT : HTAB 15: PRINT "WHICH ONE?";
  21. 140  GET TYPE$: IF TYPE$ < >"a"  AND TYPE$ < >"A"  AND TYPE$ < >"s"  AND TYPE$ < >"S"  AND TYPE$ < >"e"  AND TYPE$ < >"E"  AND TYPE$ < >"q"  AND TYPE$ < >"Q" GOTO 140
  22. 142  IF TYPE$ = "a"  OR TYPE$ = "A"  THEN TYPE$ = "ADDRESS LABELS":MAX = 4:MG = 3:PADLINE = 0
  23. 144  IF TYPE$ = "s"  OR TYPE$ = "S"  THEN TYPE$ = "SHIPPING LABELS":MAX = 6:MG = 5:PADLINE = 9
  24. 146  IF TYPE$ = "e"  OR TYPE$ = "E"  THEN TYPE$ = "ENVELOPES":MAX = 6:MG = 50:PADLINE = 15
  25. 148  HOME : IF TYPE$ = "q"  OR TYPE$ = "Q"  THEN  PRINT D$;"-/PRO/STARTUP"
  26. 150  HTAB (20 -( LEN(TYPE$)/2)): INVERSE : PRINT " ";TYPE$;" ": NORMAL : PRINT 
  27. 152  FOR LN = 1 TO MAX:L$(LN) = "":L(LN) = 0: NEXT : REM INIT VARIABLES
  28. 154  FOR LN = 1 TO MAX
  29. 156 :UP = 0: REM CLEAR UP-ARROW EDIT FLAG
  30. 158 : VTAB LN +2: HTAB 1: PRINT "Line ";LN;": ";: GOSUB 200
  31. 160 :L$(LN) = X$:L(LN) = COUNT
  32. 162 : IF UP  THEN  HTAB 1:LN = LN -2: REM UP-ARROW
  33. 164 : NEXT 
  34. 166  VTAB 20: PRINT "SET PRINTER TO TOP LINE POSITION AND": PRINT "ENTER NUMBER OF LABELS REQUIRED: "
  35. 168  VTAB 21: HTAB 34: CALL  -958: PRINT "1"; CHR$(8);: INPUT "";HM$
  36. 170  IF (HM$ = "")  THEN HM = 1: GOTO 178
  37. 172  IF ( LEFT$(HM$,1) =  CHR$(11)) GOTO 154: REM UP-ARROW
  38. 174  IF (HM$ = "0") GOTO 198
  39. 176 HM =  VAL(HM$): IF (HM <1) GOTO 166
  40. 178  PRINT D$;"PR#";SLOT: PRINT 
  41. 180  FOR LABEL = 1 TO HM: REM HOW MANY
  42. 182 : FOR LN = 1 TO MAX
  43. 184 :: PRINT  SPC( MG);L$(LN)
  44. 186 :: NEXT LN
  45. 188 : FOR PL = 1 TO PADLINE
  46. 190 :: PRINT 
  47. 192 :: NEXT PL
  48. 194  NEXT LABEL
  49. 196  PRINT D$;"PR#0"
  50. 198  HOME : GOTO 130
  51. 200  REM <CTRL-J>INPUT ROUTINE<CTRL-J>
  52. 202 HT =  PEEK(36):LIMIT = 31
  53. 204 X$ = L$(LN):COUNT = L(LN)
  54. 206  POKE 36,HT: CALL  -868: PRINT X$;
  55. 208  GET C$:OAK = ( PEEK(49249) >127)
  56. 210  IF (C$ < CHR$(32))  AND ((C$ < > CHR$(1))  AND (C$ < > CHR$(3))  AND (C$ < > CHR$(8))  AND (C$ < > CHR$(10))  AND (C$ < > CHR$(11))  AND (C$ < > CHR$(13))  AND (C$ < > CHR$(24))) GOTO 208
  57. 212  IF C$ =  CHR$(1)  THEN X$ = X$ +"ATTN: ":COUNT = COUNT +6: GOTO 206
  58. 214  IF C$ =  CHR$(3)  THEN  POP : HOME : GOTO 130
  59. 216  IF ((C$ =  CHR$(8)  OR C$ =  CHR$(127))  AND (COUNT <2))  OR (C$ =  CHR$(24)  OR OAK)  THEN X$ = "":COUNT = 0: GOTO 206: REM CANCEL LINE
  60. 218  IF C$ =  CHR$(8)  OR C$ =  CHR$(127)  THEN COUNT = COUNT -1:X$ =  LEFT$(X$,COUNT): GOTO 206
  61. 220  IF (C$ =  CHR$(11))  AND (LN = 1) GOTO 208: REM CAN'T UP-ARROW FROM TOP LINE
  62. 222  IF (C$ =  CHR$(11))  AND (LN >1)  THEN UP = 1: RETURN : REM UP-ARROW
  63. 224  IF (C$ =  CHR$(10))  OR (C$ =  CHR$(13))  THEN  PRINT : RETURN : REM UP-ARROW OR RETURN
  64. 226  IF (COUNT = LIMIT) GOTO 208
  65. 228 X$ = X$ +C$:COUNT = COUNT +1
  66. 230  GOTO 206